* Added modified CMake FindPython... modules to support using...

* Added modified CMake FindPython... modules to support using Python-a-mingw-us distribution when building Windows scripting support using MinGW

CMakeLists.txt

@@ -323,7 +323,7 @@ if(KICAD_SCRIPTING OR KICAD_SCRIPTING_MODULES)
     mark_as_advanced(PYTHON_DEST)
     message( STATUS "Python module install path: ${PYTHON_DEST}")
     find_package(PythonLibs)
-    include_directories(${PYTHON_INCLUDE_PATH}
+    include_directories(${PYTHON_INCLUDE_DIRS}
                         ./scripting)
 endif(KICAD_SCRIPTING OR KICAD_SCRIPTING_MODULES)
 

CMakeModules/CMakeFindFrameworks.cmake

+# - helper module to find OSX frameworks
+
+#=============================================================================
+# Copyright 2003-2009 Kitware, Inc.
+#
+# Distributed under the OSI-approved BSD License (the "License");
+# see accompanying file Copyright.txt for details.
+#
+# This software is distributed WITHOUT ANY WARRANTY; without even the
+# implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
+# See the License for more information.
+#=============================================================================
+# (To distribute this file outside of CMake, substitute the full
+#  License text for the above reference.)
+
+if(NOT CMAKE_FIND_FRAMEWORKS_INCLUDED)
+  set(CMAKE_FIND_FRAMEWORKS_INCLUDED 1)
+  macro(CMAKE_FIND_FRAMEWORKS fwk)
+    set(${fwk}_FRAMEWORKS)
+    if(APPLE)
+      foreach(dir
+          ~/Library/Frameworks/${fwk}.framework
+          /Library/Frameworks/${fwk}.framework
+          /System/Library/Frameworks/${fwk}.framework
+          /Network/Library/Frameworks/${fwk}.framework)
+        if(EXISTS ${dir})
+          set(${fwk}_FRAMEWORKS ${${fwk}_FRAMEWORKS} ${dir})
+        endif()
+      endforeach()
+    endif()
+  endmacro()
+endif()

CMakeModules/FindPythonInterp.cmake

+# - Find python interpreter
+# This module finds if Python interpreter is installed and determines where the
+# executables are. This code sets the following variables:
+#
+#  PYTHONINTERP_FOUND         - Was the Python executable found
+#  PYTHON_EXECUTABLE          - path to the Python interpreter
+#
+#  PYTHON_VERSION_STRING      - Python version found e.g. 2.5.2
+#  PYTHON_VERSION_MAJOR       - Python major version found e.g. 2
+#  PYTHON_VERSION_MINOR       - Python minor version found e.g. 5
+#  PYTHON_VERSION_PATCH       - Python patch version found e.g. 2
+#
+# The Python_ADDITIONAL_VERSIONS variable can be used to specify a list of
+# version numbers that should be taken into account when searching for Python.
+# You need to set this variable before calling find_package(PythonInterp).
+#
+# You can point to a preferred python install to use by setting the following
+# to the point at the root directory of the python install:
+#
+#  PYTHON_ROOT_DIR            - The root directory of the python install
+#=============================================================================
+# Copyright 2005-2010 Kitware, Inc.
+# Copyright 2011 Bjoern Ricks <bjoern.ricks@gmail.com>
+# Copyright 2012 Rolf Eike Beer <eike@sf-mail.de>
+#
+# Distributed under the OSI-approved BSD License (the "License");
+# see accompanying file Copyright.txt for details.
+#
+# This software is distributed WITHOUT ANY WARRANTY; without even the
+# implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
+# See the License for more information.
+#=============================================================================
+# (To distribute this file outside of CMake, substitute the full
+#  License text for the above reference.)
+
+unset(_Python_NAMES)
+
+set(_PYTHON1_VERSIONS 1.6 1.5)
+set(_PYTHON2_VERSIONS 2.7 2.6 2.5 2.4 2.3 2.2 2.1 2.0)
+set(_PYTHON3_VERSIONS 3.3 3.2 3.1 3.0)
+
+if(PythonInterp_FIND_VERSION)
+    if(PythonInterp_FIND_VERSION MATCHES "^[0-9]+\\.[0-9]+(\\.[0-9]+.*)?$")
+        string(REGEX REPLACE "^([0-9]+\\.[0-9]+).*" "\\1" _PYTHON_FIND_MAJ_MIN "${PythonInterp_FIND_VERSION}")
+        string(REGEX REPLACE "^([0-9]+).*" "\\1" _PYTHON_FIND_MAJ "${_PYTHON_FIND_MAJ_MIN}")
+        list(APPEND _Python_NAMES python${_PYTHON_FIND_MAJ_MIN} python${_PYTHON_FIND_MAJ})
+        unset(_PYTHON_FIND_OTHER_VERSIONS)
+        if(NOT PythonInterp_FIND_VERSION_EXACT)
+            foreach(_PYTHON_V ${_PYTHON${_PYTHON_FIND_MAJ}_VERSIONS})
+                if(NOT _PYTHON_V VERSION_LESS _PYTHON_FIND_MAJ_MIN)
+                    list(APPEND _PYTHON_FIND_OTHER_VERSIONS ${_PYTHON_V})
+                endif()
+             endforeach()
+        endif()
+        unset(_PYTHON_FIND_MAJ_MIN)
+        unset(_PYTHON_FIND_MAJ)
+    else()
+        list(APPEND _Python_NAMES python${PythonInterp_FIND_VERSION})
+        set(_PYTHON_FIND_OTHER_VERSIONS ${_PYTHON${PythonInterp_FIND_VERSION}_VERSIONS})
+    endif()
+else()
+    set(_PYTHON_FIND_OTHER_VERSIONS ${_PYTHON3_VERSIONS} ${_PYTHON2_VERSIONS} ${_PYTHON1_VERSIONS})
+endif()
+
+list(APPEND _Python_NAMES python)
+
+# Search for the preferred executable first
+if( ${PYTHON_ROOT_DIR} )
+    # Search for any of the executable names solely in the directory we've
+    # been pointed to. Failure to find the python executable here is a fatal
+    # fail.
+    find_program(PYTHON_EXECUTABLE NAMES ${_Python_NAMES}
+        PATHS ${PYTHON_ROOT_DIR}
+        NO_DEFAULT_PATH )
+else()
+    # If there is no specific path given, look for python in the path
+    find_program(PYTHON_EXECUTABLE NAMES ${_Python_NAMES})
+endif()
+
+# Set up the versions we know about, in the order we will search. Always add
+# the user supplied additional versions to the front.
+set(_Python_VERSIONS
+  ${Python_ADDITIONAL_VERSIONS}
+  ${_PYTHON_FIND_OTHER_VERSIONS}
+  )
+
+unset(_PYTHON_FIND_OTHER_VERSIONS)
+unset(_PYTHON1_VERSIONS)
+unset(_PYTHON2_VERSIONS)
+unset(_PYTHON3_VERSIONS)
+
+# Search for newest python version if python executable isn't found
+if(NOT PYTHON_EXECUTABLE)
+    
+    # If using the MINGW compiler, we mustn't find the standard python
+    # distribution because of multiple C-Runtime errors. We must instead
+    # use the Python-a-mingw-us distribution
+    if(MINGW)
+        list( APPEND _Python_PPATHS ${PYTHON_ROOT_DIR} )
+        list( APPEND _Python_PPATHS "C:/python/${_CURRENT_VERSION}.9" )
+        list( APPEND _Python_PPATHS "C:/python/${_CURRENT_VERSION}.8" )
+        list( APPEND _Python_PPATHS "C:/python/${_CURRENT_VERSION}.7" )
+        list( APPEND _Python_PPATHS "C:/python/${_CURRENT_VERSION}.6" )
+        list( APPEND _Python_PPATHS "C:/python/${_CURRENT_VERSION}.5" )
+        list( APPEND _Python_PPATHS "C:/python/${_CURRENT_VERSION}.4" )
+        list( APPEND _Python_PPATHS "C:/python/${_CURRENT_VERSION}.3" )
+        list( APPEND _Python_PPATHS "C:/python/${_CURRENT_VERSION}.2" )
+        list( APPEND _Python_PPATHS "C:/python/${_CURRENT_VERSION}.1" )
+        list( APPEND _Python_PPATHS "C:/python/${_CURRENT_VERSION}.0" )
+    else()
+        list( APPEND _Python_PPATHS [HKEY_LOCAL_MACHINE\\SOFTWARE\\Python\\PythonCore\\${_CURRENT_VERSION}\\InstallPath] )
+    endif()
+    
+    foreach(_CURRENT_VERSION ${_Python_VERSIONS})
+      set(_Python_NAMES python${_CURRENT_VERSION})
+      if(WIN32)
+        list(APPEND _Python_NAMES python)
+      endif()
+      find_program(PYTHON_EXECUTABLE
+        NAMES ${_Python_NAMES}
+        PATHS ${_Python_PPATHS}
+        )
+    endforeach()
+endif()
+
+# determine python version string
+if(PYTHON_EXECUTABLE)
+    execute_process(COMMAND "${PYTHON_EXECUTABLE}" -c
+                            "import sys; sys.stdout.write(';'.join([str(x) for x in sys.version_info[:3]]))"
+                    OUTPUT_VARIABLE _VERSION
+                    RESULT_VARIABLE _PYTHON_VERSION_RESULT
+                    ERROR_QUIET)
+    if(NOT _PYTHON_VERSION_RESULT)
+        string(REPLACE ";" "." PYTHON_VERSION_STRING "${_VERSION}")
+        list(GET _VERSION 0 PYTHON_VERSION_MAJOR)
+        list(GET _VERSION 1 PYTHON_VERSION_MINOR)
+        list(GET _VERSION 2 PYTHON_VERSION_PATCH)
+        if(PYTHON_VERSION_PATCH EQUAL 0)
+            # it's called "Python 2.7", not "2.7.0"
+            string(REGEX REPLACE "\\.0$" "" PYTHON_VERSION_STRING "${PYTHON_VERSION_STRING}")
+        endif()
+    else()
+        # sys.version predates sys.version_info, so use that
+        execute_process(COMMAND "${PYTHON_EXECUTABLE}" -c "import sys; sys.stdout.write(sys.version)"
+                        OUTPUT_VARIABLE _VERSION
+                        RESULT_VARIABLE _PYTHON_VERSION_RESULT
+                        ERROR_QUIET)
+        if(NOT _PYTHON_VERSION_RESULT)
+            string(REGEX REPLACE " .*" "" PYTHON_VERSION_STRING "${_VERSION}")
+            string(REGEX REPLACE "^([0-9]+)\\.[0-9]+.*" "\\1" PYTHON_VERSION_MAJOR "${PYTHON_VERSION_STRING}")
+            string(REGEX REPLACE "^[0-9]+\\.([0-9])+.*" "\\1" PYTHON_VERSION_MINOR "${PYTHON_VERSION_STRING}")
+            if(PYTHON_VERSION_STRING MATCHES "^[0-9]+\\.[0-9]+\\.[0-9]+.*")
+                string(REGEX REPLACE "^[0-9]+\\.[0-9]+\\.([0-9]+).*" "\\1" PYTHON_VERSION_PATCH "${PYTHON_VERSION_STRING}")
+            else()
+                set(PYTHON_VERSION_PATCH "0")
+            endif()
+        else()
+            # sys.version was first documented for Python 1.5, so assume
+            # this is older.
+            set(PYTHON_VERSION_STRING "1.4")
+            set(PYTHON_VERSION_MAJOR "1")
+            set(PYTHON_VERSION_MAJOR "4")
+            set(PYTHON_VERSION_MAJOR "0")
+        endif()
+    endif()
+    unset(_PYTHON_VERSION_RESULT)
+    unset(_VERSION)
+endif()
+
+# handle the QUIETLY and REQUIRED arguments and set PYTHONINTERP_FOUND to TRUE if
+# all listed variables are TRUE
+include(${CMAKE_CURRENT_LIST_DIR}/FindPackageHandleStandardArgs.cmake)
+FIND_PACKAGE_HANDLE_STANDARD_ARGS(PythonInterp REQUIRED_VARS PYTHON_EXECUTABLE VERSION_VAR PYTHON_VERSION_STRING)
+
+mark_as_advanced(PYTHON_EXECUTABLE)

CMakeModules/PerformFeatureChecks.cmake

@@ -56,6 +56,18 @@ macro(perform_feature_checks)
     #        mean won't fail somewhere down the line.
     check_include_file("iso646.h" HAVE_ISO646_H)
 
+    # The STDINT header file test is required because MinGW under Windows
+    # doesn't define HAVE_STDINT_H even though it does have it.
+    #
+    # We need to add it to the global compiler definitions as config.h is not
+    # included in pyport.h which is where the problem ocurrs without this
+    # fix.
+    check_include_file("stdint.h" HAVE_STDINT_H)
+    
+    if( HAVE_STDINT_H )
+        add_definitions( -DHAVE_STDINT_H )
+    endif()
+    
     # no place is this used, and "HAVE_STRINGS_H", if present in config.h then
     # conflicts with /usr/include/python2.6/Python.h.  Please rename the macro if
     # re-introduce this.

CMakeModules/SelectLibraryConfigurations.cmake

+# select_library_configurations( basename )
+#
+# This macro takes a library base name as an argument, and will choose good
+# values for basename_LIBRARY, basename_LIBRARIES, basename_LIBRARY_DEBUG, and
+# basename_LIBRARY_RELEASE depending on what has been found and set.  If only
+# basename_LIBRARY_RELEASE is defined, basename_LIBRARY, basename_LIBRARY_DEBUG,
+# and basename_LIBRARY_RELEASE will be set to the release value.  If only
+# basename_LIBRARY_DEBUG is defined, then basename_LIBRARY,
+# basename_LIBRARY_DEBUG and basename_LIBRARY_RELEASE will take the debug value.
+#
+# If the generator supports configuration types, then basename_LIBRARY and
+# basename_LIBRARIES will be set with debug and optimized flags specifying the
+# library to be used for the given configuration.  If no build type has been set
+# or the generator in use does not support configuration types, then
+# basename_LIBRARY and basename_LIBRARIES will take only the release values.
+
+#=============================================================================
+# Copyright 2009 Will Dicharry <wdicharry@stellarscience.com>
+# Copyright 2005-2009 Kitware, Inc.
+#
+# Distributed under the OSI-approved BSD License (the "License");
+# see accompanying file Copyright.txt for details.
+#
+# This software is distributed WITHOUT ANY WARRANTY; without even the
+# implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
+# See the License for more information.
+#=============================================================================
+# (To distribute this file outside of CMake, substitute the full
+#  License text for the above reference.)
+
+# This macro was adapted from the FindQt4 CMake module and is maintained by Will
+# Dicharry <wdicharry@stellarscience.com>.
+
+# Utility macro to check if one variable exists while another doesn't, and set
+# one that doesn't exist to the one that exists.
+macro( _set_library_name basename GOOD BAD )
+    if( ${basename}_LIBRARY_${GOOD} AND NOT ${basename}_LIBRARY_${BAD} )
+        set( ${basename}_LIBRARY_${BAD} ${${basename}_LIBRARY_${GOOD}} )
+        set( ${basename}_LIBRARY ${${basename}_LIBRARY_${GOOD}} )
+        set( ${basename}_LIBRARIES ${${basename}_LIBRARY_${GOOD}} )
+    endif()
+endmacro()
+
+macro( select_library_configurations basename )
+    # if only the release version was found, set the debug to be the release
+    # version.
+    _set_library_name( ${basename} RELEASE DEBUG )
+    # if only the debug version was found, set the release value to be the
+    # debug value.
+    _set_library_name( ${basename} DEBUG RELEASE )
+
+    # Set a default case, which will come into effect if
+    # -no build type is set and the generator only supports one build type
+    #  at a time (i.e. CMAKE_CONFIGURATION_TYPES is false)
+    # -${basename}_LIBRARY_DEBUG and ${basename}_LIBRARY_RELEASE are the same
+    # -${basename}_LIBRARY_DEBUG and ${basename}_LIBRARY_RELEASE are both empty
+    set( ${basename}_LIBRARY ${${basename}_LIBRARY_RELEASE} )
+    set( ${basename}_LIBRARIES ${${basename}_LIBRARY_RELEASE} )
+
+    if( ${basename}_LIBRARY_DEBUG AND ${basename}_LIBRARY_RELEASE AND
+           NOT ${basename}_LIBRARY_DEBUG STREQUAL ${basename}_LIBRARY_RELEASE )
+        # if the generator supports configuration types or CMAKE_BUILD_TYPE
+        # is set, then set optimized and debug options.
+        if( CMAKE_CONFIGURATION_TYPES OR CMAKE_BUILD_TYPE )
+            set( ${basename}_LIBRARY "" )
+            foreach( _libname IN LISTS ${basename}_LIBRARY_RELEASE )
+                list( APPEND ${basename}_LIBRARY optimized "${_libname}" )
+            endforeach()
+            foreach( _libname IN LISTS ${basename}_LIBRARY_DEBUG )
+                list( APPEND ${basename}_LIBRARY debug "${_libname}" )
+            endforeach()
+            set( ${basename}_LIBRARIES "${${basename}_LIBRARY}" )
+        endif()
+    endif()
+
+    set( ${basename}_LIBRARY ${${basename}_LIBRARY} CACHE FILEPATH
+        "The ${basename} library" )
+
+    if( ${basename}_LIBRARY )
+        set( ${basename}_FOUND TRUE )
+    endif()
+
+    mark_as_advanced( ${basename}_LIBRARY
+        ${basename}_LIBRARY_RELEASE
+        ${basename}_LIBRARY_DEBUG
+    )
+endmacro()